dbo.MG_MS_OUT_PRODUCTION_PART_LIST_HEADER_ADD

SET QUOTED_IDENTIFIER, ANSI_NULLS ON
GO

CREATE procedure dbo.MG_MS_OUT_PRODUCTION_PART_LIST_HEADER_ADD
@PARAMETER xml='' 
---XencX---with encryption
as

SET TRANSACTION ISOLATION LEVEL  READ UNCOMMITTED

declare @pemisah varchar(255)
declare @pemisah_replace varchar(255)
set @pemisah_replace='<br />'
--set @pemisah=CHAR(13) + CHAR(10) + '
'
set @pemisah = '
'

declare @resultX varchar(max)
declare @resultX2 varchar(max)

declare @XmlSts xml
declare @raw xml
declare @detail xml
declare @xStsnoheader varchar(2),
  @xStsno varchar(2),
  @xStsdes varchar(max)
   
set @xStsnoheader='07'
set @xStsno='00';
set @xStsdes='sukses'
 
BEGIN TRY
SET NOCOUNT ON
DECLARE @NOW datetime
set @NOW =GETDATE()

DECLARE 
@data_by varchar(50)
,@prod_no varchar(255)
,@prod_date date
,@ms_item_id bigint
,@prod_part_no varchar(100)
,@prod_car_line_no bigint
,@prod_qty decimal(18,4)

SELECT 
@data_by=left(ltrim(rtrim(isnull(tempTable.item.value('data_by[1]', 'varchar(100)'),''))),50)
,@prod_no=left(ltrim(rtrim(isnull(tempTable.item.value('prod_no[1]', 'varchar(255)'),''))),255)
,@prod_date=dbo.str_to_date(isnull(tempTable.item.value('prod_date[1]', 'varchar(255)'),''))
,@ms_item_id=isnull(tempTable.item.value('prod_ms_item_id[1]', 'bigint'),-1)
,@prod_part_no=left(ltrim(rtrim(isnull(tempTable.item.value('prod_ms_item_name[1]', 'varchar(100)'),''))),1000)
,@prod_car_line_no=isnull(tempTable.item.value('prod_car_line_no[1]', 'bigint'),-1)
,@prod_qty=isnull(tempTable.item.value('prod_qty[1]', 'decimal(18,4)'),0)
FROM @PARAMETER.nodes('param/field')  tempTable(item)

if @prod_no =''
 begin
  set @xStsno='02';
  set @xStsdes='Gagal, Nomor Production tidak boleh kosong' ;
  goto f
 end

if @prod_date is null
 begin
  set @xStsno='02';
  set @xStsdes='Gagal, Tanggal Production tidak boleh kosong' ;
  goto f
 end

if @prod_car_line_no= 0
 begin
  set @xStsno='02';
  set @xStsdes='Gagal,Car line No wajib di isi jika ada tipe prosses' ;
 goto f
 end

if exists(select * from vw_part_list_production_header where  ms_part_list_production_no = @prod_no and not(ms_part_list_production_status_id =-1))
 begin
  set @xStsno='02';
  set @xStsdes='Gagal, Nomor Production Sudah Ada' ;
  goto f
 end

if @ms_item_id=-1
 begin
  set @xStsno='02';
  set @xStsdes='Gagal,Part List No wajib di isi' ;
  goto f
 end
   
if not(@xStsno='00')
begin
 goto f
end

declare @ms_part_list_production_id bigint
declare @ms_part_list_production_h_status_id bigint

BEGIN TRANSACTION;    

INSERT INTO dt_ms_part_list_production_header(ms_part_list_production_no, ms_part_list_production_date, ms_item_id, quantity, ms_car_line_no, create_date, create_by, modify_date, modify_by)
VALUES      (@prod_no, @prod_date, @ms_item_id, @prod_qty, @prod_car_line_no, @NOW, @data_by, @NOW, @data_by)

SET @ms_part_list_production_id=SCOPE_IDENTITY();

INSERT INTO dt_ms_part_list_production_h_status(ms_part_list_production_id, ms_part_list_production_status_id, status_info, create_date, create_by)
VALUES        (@ms_part_list_production_id, 0, N'',@now,@data_by)

SET @ms_part_list_production_h_status_id=SCOPE_IDENTITY();
 
UPDATE dt_ms_part_list_production_header
SET ms_part_list_production_h_status_id=@ms_part_list_production_h_status_id
WHERE  ms_part_list_production_id=@ms_part_list_production_id

-- update detail
 INSERT INTO dt_ms_part_list_production_detail(ms_part_list_production_id, ms_item_id, quantity, create_date, create_by, modify_date, modify_by)
 SELECT @ms_part_list_production_id, ms_item_part_id, isnull(@prod_qty * qty_jb,0) as quantity_production, @NOW, @data_by, @NOW, @data_by
 FROM dt_ms_part_list_detail WHERE ms_item_id = @ms_item_id

COMMIT TRANSACTION; 

set  @detail=(
SELECT        
 ms_part_list_production_id AS rID 
 , ms_part_list_production_status_name AS r1 
 , @prod_no AS r2 
 , dbo.date_to_str(@prod_date ) AS r3 
 , status_info AS r4 

FROM vw_part_list_production_header
WHERE ms_part_list_production_id=@ms_part_list_production_id
for xml path('detail') )
f:

set nocount off

END TRY  
BEGIN CATCH
 IF (@@TRANCOUNT > 0)  ROLLBACK TRAN;
 
 set @xStsno='88'
 set @xStsdes= ERROR_MESSAGE() 
END CATCH

g:
set @XmlSts=(select @xStsnoheader + @xStsno as 'no', @xStsdes as 'des' for xml path('sts'))
 select  CAST( (select @XmlSts,isnull(@detail ,'') ,isnull(@raw ,'')   for xml path ('result')
)  as XML)  as dt

GO